summaryrefslogtreecommitdiff
path: root/2003/i/buspctl/acinclude.m4
diff options
context:
space:
mode:
authorschodet2003-03-31 18:37:07 +0000
committerschodet2003-03-31 18:37:07 +0000
commit55ef0ba343a4865cd927aee38a316f5e2a07aaf7 (patch)
treee25326790f3bd99dfff9d18132b571f482cf736b /2003/i/buspctl/acinclude.m4
parentbeadc114b3a66c3397e2574e441258c92678cb5e (diff)
Initial revision
Diffstat (limited to '2003/i/buspctl/acinclude.m4')
-rw-r--r--2003/i/buspctl/acinclude.m446
1 files changed, 46 insertions, 0 deletions
diff --git a/2003/i/buspctl/acinclude.m4 b/2003/i/buspctl/acinclude.m4
new file mode 100644
index 0000000..2327b3f
--- /dev/null
+++ b/2003/i/buspctl/acinclude.m4
@@ -0,0 +1,46 @@
+dnl Available from the GNU Autoconf Macro Archive at:
+dnl http://www.gnu.org/software/ac-archive/htmldoc/vl_lib_readline.html
+dnl
+AC_DEFUN([VL_LIB_READLINE], [
+ AC_CACHE_CHECK([for a readline compatible library],
+ vl_cv_lib_readline, [
+ ORIG_LIBS="$LIBS"
+ for readline_lib in readline edit editline; do
+ for termcap_lib in "" termcap curses ncurses; do
+ if test -z "$termcap_lib"; then
+ TRY_LIB="-l$readline_lib"
+ else
+ TRY_LIB="-l$readline_lib -l$termcap_lib"
+ fi
+ LIBS="$ORIG_LIBS $TRY_LIB"
+ AC_TRY_LINK_FUNC(readline, vl_cv_lib_readline="$TRY_LIB")
+ if test -n "$vl_cv_lib_readline"; then
+ break
+ fi
+ done
+ if test -n "$vl_cv_lib_readline"; then
+ break
+ fi
+ done
+ if test -z "$vl_cv_lib_readline"; then
+ vl_cv_lib_readline="no"
+ LIBS="$ORIG_LIBS"
+ fi
+ ])
+
+ if test "$vl_cv_lib_readline" != "no"; then
+ AC_DEFINE(HAVE_LIBREADLINE, 1,
+ [Define if you have a readline compatible library])
+ AC_CHECK_HEADERS(readline.h readline/readline.h)
+ AC_CACHE_CHECK([whether readline supports history],
+ vl_cv_lib_readline_history, [
+ vl_cv_lib_readline_history="no"
+ AC_TRY_LINK_FUNC(add_history, vl_cv_lib_readline_history="yes")
+ ])
+ if test "$vl_cv_lib_readline_history" = "yes"; then
+ AC_DEFINE(HAVE_READLINE_HISTORY, 1,
+ [Define if your readline library has \`add_history'])
+ AC_CHECK_HEADERS(history.h readline/history.h)
+ fi
+ fi
+])