summaryrefslogtreecommitdiff
path: root/src/Propellor/Property/Mysql.hs
blob: f7639a2925f7b26b43a11e6face79f0e0efcd642 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
-- | Maintainer: Nicolas Schodet <nico@ni.fr.eu.org>
--
-- Support for MySQL/MariaDB server.
--
-- Enough to setup a database with a dedicated user for web applications.

module Propellor.Property.Mysql (
	Database(..),
	Privilege(..),
	allPrivileges,
	basicPrivileges,
	basicStructurePrivileges,
	installed,
	databaseExists,
	userGrantedOnDatabase,
	userGranted,
) where

import Propellor
import Propellor.Base
import Data.List
import qualified Propellor.Property.Apt as Apt

-- | A database is defined by its name.
newtype Database = Database String

data Privilege
	= Select
	| Insert
	| Update
	| Delete
	| Create
	| Drop
	| Index
	| Alter
	| CreateTemporaryTables
	| LockTables
	| Execute
	| CreateView
	| ShowView
	| CreateRoutine
	| AlterRoutine
	| Event
	| Trigger
	deriving (Eq, Ord, Enum)

sqlPrivilege :: Privilege -> String
sqlPrivilege Select = "SELECT"
sqlPrivilege Insert = "INSERT"
sqlPrivilege Update = "UPDATE"
sqlPrivilege Delete = "DELETE"
sqlPrivilege Create = "CREATE"
sqlPrivilege Drop = "DROP"
sqlPrivilege Index = "INDEX"
sqlPrivilege Alter = "ALTER"
sqlPrivilege CreateTemporaryTables = "CREATE TEMPORARY TABLES"
sqlPrivilege LockTables = "LOCK TABLES"
sqlPrivilege Execute = "EXECUTE"
sqlPrivilege CreateView = "CREATE VIEW"
sqlPrivilege ShowView = "SHOW VIEW"
sqlPrivilege CreateRoutine = "CREATE ROUTINE"
sqlPrivilege AlterRoutine = "ALTER ROUTINE"
sqlPrivilege Event = "EVENT"
sqlPrivilege Trigger = "TRIGGER"

-- | All privileges
allPrivileges :: [Privilege]
allPrivileges = [Select .. Trigger]

-- | Basic privileges needed to use a classic database already created.
basicPrivileges :: [Privilege]
basicPrivileges =
	[ Select
	, Insert
	, Update
	, Delete
	]

-- | Classic privileges needed to create a database and its structure.
basicStructurePrivileges :: [Privilege]
basicStructurePrivileges =
	[ Select
	, Insert
	, Update
	, Delete
	, Create
	, Drop
	, Index
	, Alter
	]

-- | Make sure a server is installed.
installed :: RevertableProperty DebianLike DebianLike
installed = install <!> remove
  where
	install = Apt.installed server
	remove = Apt.removed server
	server = ["default-mysql-server"]

-- | Create a database if it does not exist.  When reverted, remove the
-- database.
databaseExists :: Database -> RevertableProperty DebianLike DebianLike
databaseExists (Database dbname) =
	setup <!> cleanup
  where
	setup :: Property DebianLike
	setup = setup' `requires` installed

	cleanup :: Property DebianLike
	cleanup = cleanup' `requires` installed

	-- Test for database existance and create it if needed.
	setup' :: Property UnixLike
	setup' = property' desc $ \w -> do
		present <- liftIO $ dbPresent
		ensureProperty w $ setupprop present
	  where
		desc = "database " ++ dbname ++ " exists"

	setupprop :: Bool -> Property UnixLike
	setupprop True = doNothing
	setupprop False = cmdProperty "mysqladmin" ["create", dbname]
		`assume` MadeChange

	-- Test for database existance and drop it if needed.
	cleanup' :: Property UnixLike
	cleanup' = property' desc $ \w -> do
		present <- liftIO $ dbPresent
		ensureProperty w $ cleanupprop present
	  where
		desc = "database " ++ dbname ++ " does not exist"

	cleanupprop :: Bool -> Property UnixLike
	cleanupprop True = cmdProperty "mysqladmin" ["drop", "-f", dbname]
		`assume` MadeChange
	cleanupprop False = doNothing

	-- Is database present?
	dbPresent :: IO Bool
	dbPresent = (== trueResult) <$> readProcess "mysql" ["-BNre", sql]
	  where
		sql = "SHOW DATABASES LIKE " ++ qdbname
		qdbname = sqlQuote '\'' dbname
		trueResult = dbname ++ "\n"

-- Create an user and make sure he has grants on the specific database but no
-- other grant.
userGrantedOnDatabase
	:: IsContext c
	=> User
	-> Database
	-> [Privilege]
	-> c
	-> RevertableProperty (HasInfo + DebianLike) DebianLike
userGrantedOnDatabase user@(User username) (Database dbname) privs context =
	userGranted' user privs context setupDesc setupSql userGrants
  where
	setupDesc = "user " ++ username ++ " granted on database " ++ dbname
	setupSql quser hash privList =
		"GRANT " ++ privList ++ " ON " ++ privLevel
		++ " TO " ++ quser
		++ " IDENTIFIED BY PASSWORD '" ++ hash ++ "'"
	-- Expected user grants as output by MySQL.
	userGrants quser hash privList =
		"GRANT USAGE ON *.* TO " ++ quser
		++ " IDENTIFIED BY PASSWORD '" ++ hash ++ "'\n"
		++ "GRANT " ++ privList ++ " ON " ++ privLevel
		++ " TO " ++ quser ++ "\n"
	-- Privilege level for database access.
	privLevel = (sqlQuote '`' dbname) ++ ".*"

-- Create an user and make sure he has global grants but no other grant.
userGranted
	:: IsContext c
	=> User
	-> [Privilege]
	-> c
	-> RevertableProperty (HasInfo + DebianLike) DebianLike
userGranted user@(User username) privs context =
	userGranted' user privs context setupDesc setupSql userGrants
  where
	setupDesc = "user " ++ username ++ " granted"
	setupSql quser hash privList =
		"GRANT " ++ privList ++ " ON *.*"
		++ " TO " ++ quser
		++ " IDENTIFIED BY PASSWORD '" ++ hash ++ "'"
	-- Expected user grants as output by MySQL.
	userGrants quser hash privList =
		"GRANT " ++ privList ++ " ON *.* TO " ++ quser
		++ " IDENTIFIED BY PASSWORD '" ++ hash ++ "'\n"

-- Common code to grant or remove an user.
userGranted'
	:: IsContext c
	=> User
	-> [Privilege]
	-> c
	-> String
	-> (String -> String -> String -> String)
	-> (String -> String -> String -> String)
	-> RevertableProperty (HasInfo + DebianLike) DebianLike
userGranted' (User username) privs context setupDesc setupSql userGrants =
	setup <!> cleanup
  where
	setup :: Property (HasInfo + DebianLike)
	setup = setup' `requires` installed

	cleanup :: Property DebianLike
	cleanup = cleanup' `requires` installed

	-- Check user grants and reset them if needed.
	setup' :: Property (HasInfo + UnixLike)
	setup' = withPrivData (Password username) context $ \getpassword ->
		property' setupDesc $ \w -> getpassword $ \priv -> do
			hash <- liftIO $ hashPassword $ privDataVal priv
			curGrants <- liftIO $ getUserGrants
			let match = curGrants ==
				(userGrants quser hash privList)
			ensureProperty w $ setupprop match hash

	setupprop :: Bool -> String -> Property UnixLike
	setupprop True _ = doNothing
	setupprop False hash = cmdProperty "mysql" ["-BNre", sql]
		`assume` MadeChange
	  where
		sql = "DROP USER IF EXISTS " ++ quser ++ ";" ++
			(setupSql quser hash privList)

	-- Test for user existance and drop it if needed.
	cleanup' :: Property UnixLike
	cleanup' =
		property' desc $ \w -> do
			curGrants <- liftIO $ getUserGrants
			ensureProperty w $ cleanupprop $ curGrants /= ""
	  where
		desc = "user " ++ username ++ " does not exist"

	cleanupprop :: Bool -> Property UnixLike
	cleanupprop False = doNothing
	cleanupprop True = cmdProperty "mysql" ["-BNre", sql]
		`assume` MadeChange
	  where
		sql = "DROP USER " ++ quser

	-- Request MySQL to hash a password.
	hashPassword :: String -> IO String
	hashPassword password =
		Data.List.head . lines <$>
			writeReadProcessEnv "mysql" ["-BNr"] Nothing
				(Just writer) Nothing
	  where
		writer h = hPutStr h sql
		sql = "SELECT PASSWORD(" ++ qpassword ++ ")"
		qpassword = sqlQuote '\'' password

	-- Request current user grants from MySQL.
	getUserGrants :: IO String
	getUserGrants =
		catchDefaultIO "" $ readProcess "mysql" ["-BNre", sql]
	  where
		sql = "SHOW GRANTS FOR " ++ quser

	-- Privilege list as output by MySQL.
	privList = intercalate ", " $ map sqlPrivilege $ nub $ sort privs
	-- Qualified user name.
	quser = (sqlQuote '\'' username) ++ "@'localhost'"

-- | Quote a string using the given quote character.
sqlQuote :: Char -> String -> String
sqlQuote quote s =
	[quote] ++ (concatMap escape s) ++ [quote]
  where
	escape c
		| c == quote = [quote, quote]
		| otherwise = [c]