summaryrefslogtreecommitdiff
path: root/src/Propellor/Property/Firewall.hs
blob: d7a2d9bcce64f12e29aa2babbe90bb8729440858 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
-- | Maintainer: Arnaud Bailly <arnaud.oqube@gmail.com>
--
-- Properties for configuring firewall (iptables) rules

module Propellor.Property.Firewall (
	rule,
	installed,
	Chain(..),
	Table(..),
	TargetFilter(..),
	TargetNat(..),
	TargetMangle(..),
	TargetRaw(..),
	TargetSecurity(..),
	Proto(..),
	Rules(..),
	ConnectionState(..),
	IPWithMask(..),
	fromIPWithMask
) where

import Data.Monoid
import Data.Char
import Data.List

import Propellor.Base
import qualified Propellor.Property.Apt as Apt
import qualified Propellor.Property.Network as Network

installed :: Property NoInfo
installed = Apt.installed ["iptables"]

rule :: Chain -> Table -> Rules -> Property NoInfo
rule c t rs = property ("firewall rule: " <> show r) addIpTable
  where
	r = Rule c t rs
	addIpTable = liftIO $ do
		let args = toIpTable r
		exist <- boolSystem "iptables" (chk args)
		if exist
			then return NoChange
			else toResult <$> boolSystem "iptables" (add args)
	add params = Param "-A" : params
	chk params = Param "-C" : params

toIpTable :: Rule -> [CommandParam]
toIpTable r =  map Param $
	show (ruleChain r) :
	toIpTableArg (ruleRules r) ++ toIpTableTable (ruleTable r)

toIpTableArg :: Rules -> [String]
toIpTableArg Everything = []
toIpTableArg (Proto proto) = ["-p", map toLower $ show proto]
toIpTableArg (DPort (Port port)) = ["--dport", show port]
toIpTableArg (DPortRange (Port f, Port t)) =
	["--dport", show f ++ ":" ++ show t]
toIpTableArg (InIFace iface) = ["-i", iface]
toIpTableArg (OutIFace iface) = ["-o", iface]
toIpTableArg (Ctstate states) =
	[ "-m"
	, "conntrack"
	, "--ctstate", intercalate "," (map show states)
	]
toIpTableArg (Source ipwm) =
	[ "-s"
	, intercalate "," (map fromIPWithMask ipwm)
	]
toIpTableArg (Destination ipwm) =
	[ "-d"
	, intercalate "," (map fromIPWithMask ipwm)
	]
toIpTableArg (r :- r') = toIpTableArg r <> toIpTableArg r'

data IPWithMask = IPWithNoMask IPAddr | IPWithIPMask IPAddr IPAddr | IPWithNumMask IPAddr Int
	deriving (Eq, Show)

fromIPWithMask :: IPWithMask -> String
fromIPWithMask (IPWithNoMask ip) = fromIPAddr ip
fromIPWithMask (IPWithIPMask ip ipm) = fromIPAddr ip ++ "/" ++ fromIPAddr ipm
fromIPWithMask (IPWithNumMask ip m) = fromIPAddr ip ++ "/" ++ show m

data Rule = Rule
	{ ruleChain :: Chain
	, ruleTable :: Table
	, ruleRules :: Rules
	} deriving (Eq, Show)

data Table = Filter TargetFilter | Nat TargetNat | Mangle TargetMangle | Raw TargetRaw | Security TargetSecurity
	deriving (Eq, Show)

toIpTableTable :: Table -> [String]
toIpTableTable f = ["-t", table, "-j", target]
  where
	(table, target) = toIpTableTable' f

toIpTableTable' :: Table -> (String, String)
toIpTableTable' (Filter target) = ("filter", fromTargetFilter target)
toIpTableTable' (Nat target) = ("nat", fromTargetNat target)
toIpTableTable' (Mangle target) = ("mangle", fromTargetMangle target)
toIpTableTable' (Raw target) = ("raw", fromTargetRaw target)
toIpTableTable' (Security target) = ("security", fromTargetSecurity target)

data Chain = INPUT | OUTPUT | FORWARD
	deriving (Eq, Show)

data TargetFilter = ACCEPT | REJECT | DROP | LOG | FilterCustom String
	deriving (Eq, Show)

fromTargetFilter :: TargetFilter -> String
fromTargetFilter ACCEPT = "ACCEPT"
fromTargetFilter REJECT = "REJECT"
fromTargetFilter DROP = "DROP"
fromTargetFilter LOG = "LOG"
fromTargetFilter (FilterCustom f) = f

data TargetNat = NatPREROUTING | NatOUTPUT | NatPOSTROUTING | NatCustom String
	deriving (Eq, Show)

fromTargetNat :: TargetNat -> String
fromTargetNat NatPREROUTING = "PREROUTING"
fromTargetNat NatOUTPUT = "OUTPUT"
fromTargetNat NatPOSTROUTING = "POSTROUTING"
fromTargetNat (NatCustom f) = f

data TargetMangle = ManglePREROUTING | MangleOUTPUT | MangleINPUT | MangleFORWARD | ManglePOSTROUTING | MangleCustom String
	deriving (Eq, Show)

fromTargetMangle :: TargetMangle -> String
fromTargetMangle ManglePREROUTING = "PREROUTING"
fromTargetMangle MangleOUTPUT = "OUTPUT"
fromTargetMangle MangleINPUT = "INPUT"
fromTargetMangle MangleFORWARD = "FORWARD"
fromTargetMangle ManglePOSTROUTING = "POSTROUTING"
fromTargetMangle (MangleCustom f) = f

data TargetRaw = RawPREROUTING | RawOUTPUT | RawCustom String
	deriving (Eq, Show)

fromTargetRaw :: TargetRaw -> String
fromTargetRaw RawPREROUTING = "PREROUTING"
fromTargetRaw RawOUTPUT = "OUTPUT"
fromTargetRaw (RawCustom f) = f

data TargetSecurity = SecurityINPUT | SecurityOUTPUT | SecurityFORWARD | SecurityCustom String
	deriving (Eq, Show)

fromTargetSecurity :: TargetSecurity -> String
fromTargetSecurity SecurityINPUT = "INPUT"
fromTargetSecurity SecurityOUTPUT = "OUTPUT"
fromTargetSecurity SecurityFORWARD = "FORWARD"
fromTargetSecurity (SecurityCustom f) = f

data Proto = TCP | UDP | ICMP
	deriving (Eq, Show)

data ConnectionState = ESTABLISHED | RELATED | NEW | INVALID
	deriving (Eq, Show)

data Rules
	= Everything
	| Proto Proto
	-- ^There is actually some order dependency between proto and port so this should be a specific
	-- data type with proto + ports
	| DPort Port
	| DPortRange (Port,Port)
	| InIFace Network.Interface
	| OutIFace Network.Interface
	| Ctstate [ ConnectionState ]
	| Source [ IPWithMask ]
	| Destination [ IPWithMask ]
	| Rules :- Rules   -- ^Combine two rules
	deriving (Eq, Show)

infixl 0 :-

instance Monoid Rules where
	mempty  = Everything
	mappend = (:-)