summaryrefslogtreecommitdiff
path: root/p/tools/todo.pl
blob: b615f0d020b291f013bfcbdd131fa1659273ada2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
#!/usr/bin/perl -w
#
# Tool to parse todo files.
#
use strict;
use locale;
use Template;
use Getopt::Long qw(:config no_ignore_case no_auto_abbrev bundling);

# Parse a todo file and add tasks to \%todos.
sub parse_todo
{
    my ($todos, $path, $file, $filter) = @_;
    #print "$path...\n";
    my $owners;
    local $_;
    local *FILE;
    # Check for duplicates and create task list.
    die "duplicate path: $path" if exists $$todos{''};
    $$todos{''} = [ ];
    my $tasks = $$todos{''};
    # Open file.
    open FILE, "<$file" or die "$file: $!";
    # Read each lines.
    while (<FILE>)
    {
	chomp;
	# Task line.
	/^([-+=x]) (?:\[(\d\d\/\d\d\/\d{4})\] |)(?:\(([^)]+)\) |)(.+)$/ and do {
	    my ($state, $deadline, $owners, $text) =
		($1, $2, $3 || $owners, $4);
	    my @owners;
	    @owners = split /, */, $owners if defined $owners;
	    # Read next lines.
	    while (<FILE>)
	    {
		chomp;
		# Continued task, new paragraph.
		/^  $/ and $text .= "\n", next;
		# Continued task.
		/^  (.*)$/ and $text .= ' ' . $1, next;
		last;
	    }
	    # Add task.
	    my %task = (
		state => $state,
		deadline => $deadline,
		owners => [ @owners ],
		text => $text,
	    );
	    push @$tasks, \%task if &$filter (%task);
	    last unless defined $_;
	    redo;
	};
	# Default owner line.
	/^\(([^)]+)\)$/ and $owners = $1, next;
	# Subtask line.
	/^[-\w\d]+$/ and do {
	    my $path = $path . '/' . $_;
	    $$todos{$_} ||= { };
	    my $todos = $$todos{$_};
	    die "duplicate path: $path" if exists $$todos{''};
	    $$todos{''} = [ ];
	    $tasks = $$todos{''};
	    next;
	};
	# Empty line.
	/^$/ and next;
	# Else, die.
	die "Invalid format in file $file at line $.\n";
    }
    # Close file.
    close FILE;
}

# Read dir and parse each todo files it contains.
sub parse_dir
{
    my ($todos, $path, $dir, $filter) = @_;
    local $_;
    local @_;
    local *DIR;
    # Read files list.
    opendir DIR, $dir or die "$dir: $!";
    @_ = readdir DIR;
    closedir DIR;
    # Filter todo files & dirs lists.
    my @todofiles = grep { !/^\./ && /\.todo$/ && -f "$dir/$_" } @_;
    s/\.todo$// foreach @todofiles;
    my @tododirs = grep { !/^\./ && -d "$dir/$_" } @_;
    # Create empty hashes.
    $$todos{$_} ||= { } foreach @todofiles, @tododirs;
    # Process each todo files.
    parse_todo ($$todos{$_}, "$path/$_", "$dir/$_.todo", $filter)
	foreach @todofiles;
    # Recurse into each dirs.
    parse_dir ($$todos{$_}, "$path/$_", "$dir/$_", $filter)
	foreach @tododirs;
}

# Drop empty nodes.
sub drop_empty
{
    my ($todos) = @_;
    for (keys %$todos)
    {
	if ($_)
	{
	    # Recurse.
	    drop_empty ($$todos{$_});
	    # Drop if empty.
	    delete $$todos{$_} unless scalar keys %{$$todos{$_}};
	}
	else
	{
	    delete $$todos{$_} unless scalar @{$$todos{$_}};
	}
    }
}

# Output todo tree file.
sub output_tree
{
    my ($config, $t) = @_;
    my $tt = new Template ({
	    INCLUDE_PATH => $$config{'template-dir'},
	    PRE_CHOMP => 1,
	    POST_CHOMP => 1,
	    INTERPOLATE => 1,
	});
    $tt->process ('todo.' . $$config{'format'} . '.tt', {
	    'tasks' => $t,
	    'owner' => !defined $$config{'owner'},
	})
	or die $tt->error;
}

# Print short help.
sub usage
{
    print <<EOF;
todo.pl - Parse todo files.

Usage: todo.pl [OPTIONS]

Options:
  -t, --todo-dir=DIR      Set the todo directory (defaults to'../todo').
  -T, --template-dir=DIR  Set the template directory (defaults to '.').
  -f, --format=FORMAT     Set the output format ('text' or 'html', defaults to
                          'text').
  -k, --keep-empty        Keep empty sections.
  -o, --owner=OWNER       Output only task for OWNER.
  -O, --opened            Output only opened tasks.
  -s, --scheduled         Output only scheduled task (i.e. with a deadline).
  -d, --dump              Dump todo hash instead of normal output.
  -h, --help              Print this help screen.
EOF
}

# Parse options.
sub config
{
    my %config = (
	'todo-dir' => '../todo',
	'template-dir' => '.',
	'format' => 'text',
    );
    GetOptions (\%config,
	'todo-dir|t=s',
	'template-dir|T=s',
	'format|f=s',
	'keep-empty|k',
	'owner|o=s',
	'open|O',
	'scheduled|s',
	'dump|d',
	'help|h',
    ) or die;
    usage () and exit 0 if (exists ($config{help}));
    return %config;
}

my %todos;

my %config = config ();
my $filter = sub {
    my %t = @_;
    if ($config{'owner'})
    {
	return 0 unless grep { $_ =~ /$config{'owner'}/i } @{$t{'owners'}};
    }
    if ($config{'open'})
    {
	return 0 unless $t{'state'} =~ /[-=]/;
    }
    if ($config{'scheduled'})
    {
	return 0 unless defined $t{'deadline'};
    }
    1;
};
parse_dir (\%todos, '', $config{'todo-dir'}, $filter);
drop_empty \%todos unless $config{'keep-empty'};
if (exists ($config{'dump'}))
{
    use Data::Dumper;
    print Dumper \%todos;
}
else
{
    output_tree (\%config, \%todos);
}