summaryrefslogtreecommitdiff
path: root/2005/i/robert/src/config/parser.yy
blob: 3397c57b66bbb8cab754b2f4cc504f32e96d797d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
%{
// robert - programme du robot 2005. {{{
//
// Copyright (C) 2005 Nicolas Schodet
//
// Robot APB Team/Efrei 2005.
//        Web: http://assos.efrei.fr/robot/
//      Email: robot AT efrei DOT fr
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation; either version 2 of the License, or
// (at your option) any later version.
// 
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
//
// }}}
#define YYPARSE_PARAM scanner
#define YYLEX_PARAM scanner

#include "config/config.hh"
#include "config/config_data.hh"
#include "config/parser_extra.hh"

// Fichiers d'en-t�te g�n�r�s.
#include "parser.hh"
#include "lexer.hh"

#include <iostream> // XXX � virer.

void yyerror (const char *);

#undef yyextra
#define yyextra (yyget_extra (scanner))

%}

%error-verbose
%pure-parser
%defines
%union {
	char c;
	int i;
	double f;
	bool b;
	std::string *s;
	struct {
		any *a;
		Config::IntList *il;
		Config::FloatList *fl;
		Config::StringList *sl;
	} a;
}

%token<c> UNKNOWN
%token<i> INT
%token<f> FLOAT
%token<s> ID STRING
%token<b> BOOLEAN
%token IMG DATA

%type<a> int_list
%type<a> float_list
%type<a> string_list

%destructor { delete $$; } ID STRING
%destructor { delete $$.a; } int_list
%destructor { delete $$.a; } float_list
%destructor { delete $$.a; } string_list

%%

input:
	  /* Nothing. */
	| confitem
	| input '\n' confitem
	| input '\n'
;

confitem:
	  ID '=' INT	{
		yyextra->configData.add (*$1, $3);
		delete $1;
		}
	| ID '=' FLOAT	{
		yyextra->configData.add (*$1, $3);
		delete $1;
		}
	| ID '=' STRING	{
		yyextra->configData.add (*$1, *$3);
		delete $1;
		delete $3;
		}
	| ID '=' '(' int_list ')'	{
		yyextra->configData.add (*$1, *$4.a);
		delete $1;
		delete $4.a;
		}
	| ID '=' '(' float_list ')'	{
		yyextra->configData.add (*$1, *$4.a);
		delete $1;
		delete $4.a;
		}
	| ID '=' '(' string_list ')'	{
		yyextra->configData.add (*$1, *$4.a);
		delete $1;
		delete $4.a;
		}
;

int_list:
	  INT		{
		$$.a = new any (Config::IntList ());
		$$.il = any_cast<Config::IntList> ($$.a);
		$$.il->push_back ($1);
	  }
	| int_list INT	{
		$1.il->push_back ($2);
		$$ = $1;
	}
;

float_list:
	  FLOAT		{
		$$.a = new any (Config::FloatList ());
		$$.fl = any_cast<Config::FloatList> ($$.a);
		$$.fl->push_back ($1);
	  }
	| float_list FLOAT	{
		$1.fl->push_back ($2);
		$$ = $1;
	}
;

string_list:
	  STRING	{
		$$.a = new any (Config::StringList ());
		$$.sl = any_cast<Config::StringList> ($$.a);
		$$.sl->push_back (*$1);
		delete $1;
	  }
	| string_list STRING	{
		$1.sl->push_back (*$2);
		$$ = $1;
		delete $2;
	}
;

%%

void yyerror (const char *e)
{
    std::cerr << e << std::endl;
}

/* Shut up warning for this wrongly declared static function. */
static int
yy_init_globals (yyscan_t yyscanner)
{
    return yy_init_globals (yyscanner);
}

/* vim:ft=yacc:
*/